Gecko [ explonortespa.com ]

Name	Size	Permission	Date
bash_timestamps.sh	69 B	-rw-r--r--	2024-04-13 00:01
colorgrep.csh	196 B	-rw-r--r--	2018-08-12 04:47
colorgrep.sh	201 B	-rw-r--r--	2018-08-12 04:47
colorls.csh	1.7 KB	-rw-r--r--	2025-12-18 10:41
colorls.sh	1.57 KB	-rw-r--r--	2025-12-18 10:41
colorsysstat.csh	69 B	-rw-r--r--	2024-07-03 05:37
colorsysstat.sh	56 B	-rw-r--r--	2024-07-03 05:37
colorxzgrep.csh	162 B	-rw-r--r--	2022-06-14 08:58
colorxzgrep.sh	183 B	-rw-r--r--	2022-06-14 08:58
colorzgrep.csh	216 B	-rw-r--r--	2022-04-20 07:03
colorzgrep.sh	220 B	-rw-r--r--	2022-04-20 07:03
cpanel-user-commands.sh	513 B	-rw-r--r--	2024-04-12 23:58
csh.local	80 B	-rw-r--r--	2023-05-15 10:46
debuginfod.csh	674 B	-rw-r--r--	2025-08-25 08:55
debuginfod.sh	596 B	-rw-r--r--	2025-08-25 08:55
gawk.csh	1.08 KB	-rw-r--r--	2017-12-14 14:53
gawk.sh	757 B	-rw-r--r--	2017-12-14 14:53
lang.csh	2.43 KB	-rw-r--r--	2023-05-15 10:46
lang.sh	2.26 KB	-rw-r--r--	2023-05-15 10:46
less.csh	500 B	-rw-r--r--	2024-07-02 15:57
less.sh	253 B	-rw-r--r--	2024-07-02 15:57
locallib.csh	240 B	-rwxr-xr-x	2024-04-13 00:01
locallib.sh	288 B	-rwxr-xr-x	2024-04-13 00:01
modules.csh	105 B	-rw-r--r--	2023-10-14 15:46
modules.sh	448 B	-rw-r--r--	2023-10-14 15:46
scl-init.csh	284 B	-rw-r--r--	2017-08-25 05:23
scl-init.sh	637 B	-rw-r--r--	2017-08-25 05:23
sh.local	81 B	-rw-r--r--	2023-05-15 10:46
which2.csh	120 B	-rw-r--r--	2025-08-26 04:51
which2.sh	628 B	-rw-r--r--	2025-08-26 04:51

Rename

# /etc/profile.d/lang.csh - exports environment variables, and provides fallback
#                          for CJK languages that can't be displayed in console.

if (${?LANG}) then
    set LANG_backup=${LANG}
endif

foreach config (/etc/locale.conf "${HOME}/.i18n")
    if (-f "${config}") then
        # NOTE: We are using eval & sed here to avoid invoking of any commands & functions from those files.
        eval `/usr/bin/sed -r -e 's/^[[:blank:]]*([[:upper:]_]+)=([[:print:][:digit:]\._-]+|"[[:print:][:digit:]\._-]+")/setenv \1 \2;/;t;d' ${config}`
    endif
end

if (${?LANG_backup}) then
    setenv LANG "${LANG_backup}"
endif

unset LANG_backup config

# ----------------------------------------------

# The LC_ALL is not supposed to be set in /etc/locale.conf according to 'man 5 locale.conf'.
# If it is set, then we we expect it is user's explicit override (most likely from ~/.i18n file).
# See 'man 7 locale' for more info about LC_ALL.
if (${?LC_ALL}) then
    if (${LC_ALL} != ${LANG}) then
        setenv LC_ALL
    else
        unsetenv LC_ALL
    endif
endif

# The ${LANG} manipulation is necessary only in virtual terminal (a.k.a. console - /dev/tty*):
set in_console=`/usr/bin/tty | /usr/bin/grep -vc -e '/dev/tty'`

if (${?LANG} && ${?TERM}) then
    if (${TERM} == 'linux' && $in_console == 0) then
        set utf8_used=`echo ${LANG} | /usr/bin/grep -vc -E -i -e '^.+\.utf-?8$'`

if (${utf8_used} == 0) then
            switch (${LANG})
                case en_IN*:
                    breaksw

case ja*:
                case ko*:
                case si*:
                case zh*:
                case ar*:
                case fa*:
                case he*:
                case *_IN*:
                    setenv LANG en_US.UTF-8
                    breaksw
            endsw
        else
            switch (${LANG})
                case en_IN*:
                    breaksw
                case ja*:
                case ko*:
                case si*:
                case zh*:
                case ar*:
                case fa*:
                case he*:
                case *_IN*:
                    setenv LANG en_US
                    breaksw
            endsw
        endif

# NOTE: We are not exporting the ${LANG} here again on purpose.
        #       If user starts GUI session from console manually, then
        #       the previously set LANG should be okay to use.
    endif
endif

unset in_console utf8_used